q_indices.F90

Go to the documentation of this file.

module q_indices_mod
  use conversions_mod, only : conv_to_string
  use logging_mod, only : log_info, log_error, log_master_log
  implicit none

#ifndef TEST_MODE
  private
#endif

  integer, parameter :: n_maxqs=100
  integer, parameter :: n_maxqname=100

  
  type :: q_metadata_type
     character(n_maxqname) :: name
     logical :: l_used=.false.
  end type q_metadata_type
  
  
  type(q_metadata_type) :: q_register(n_maxqs)


  ! standard names
  type :: standard_q_names_type
     character(LEN=6 ) :: vapour                 = 'vapour' 
     character(LEN=17) :: cloud_liquid_mass      = 'cloud_liquid_mass'
     character(LEN=9 ) :: rain_mass              = 'rain_mass'
     character(LEN=8 ) :: ice_mass               = 'ice_mass'
     character(LEN=9 ) :: snow_mass              = 'snow_mass'
     character(LEN=12) :: graupel_mass           = 'graupel_mass'
     character(LEN=19) :: cloud_liquid_number    = 'cloud_liquid_number'
     character(LEN=11) :: rain_number            = 'rain_number'
     character(LEN=10) :: ice_number             = 'ice_number'
     character(LEN=11) :: snow_number            = 'snow_number'
     character(LEN=14) :: graupel_number         = 'graupel_number'
     character(LEN=17) :: rain_third_moment      = 'rain_third_moment'
     character(LEN=17) :: snow_third_moment      = 'snow_third_moment'
     character(LEN=20) :: graupel_third_moment   = 'graupel_third_moment'
     character(LEN=15) :: aitken_sol_mass        = 'aitken_sol_mass'
     character(LEN=17) :: aitken_sol_number      = 'aitken_sol_number'
     character(LEN=14) :: accum_sol_mass         = 'accum_sol_mass'
     character(LEN=16) :: accum_sol_number       = 'accum_sol_number'
     character(LEN=15) :: coarse_sol_mass        = 'coarse_sol_mass'
     character(LEN=17) :: coarse_sol_number      = 'coarse_sol_number'
     character(LEN=17) :: active_sol_liquid      = 'active_sol_liquid'
     character(LEN=15) :: active_sol_rain        = 'active_sol_rain'
     character(LEN=16) :: coarse_dust_mass       = 'coarse_dust_mass'
     character(LEN=18) :: coarse_dust_number     = 'coarse_dust_number'
     character(LEN=16) :: active_insol_ice       = 'active_insol_ice'
     character(LEN=14) :: active_sol_ice         = 'active_sol_ice'
     character(LEN=19) :: active_insol_liquid    = 'active_insol_liquid'
     character(LEN=16) :: accum_insol_mass       = 'accum_insol_mass'
     character(LEN=18) :: accum_insol_number     = 'accum_insol_number'
     character(LEN=17) :: active_sol_number      = 'active_sol_number'
     character(LEN=19) :: active_insol_number    = 'active_insol_number'
  end type standard_q_names_type

  type(standard_q_names_type) :: standard_q_names

  public q_metadata_type, get_q_index, get_indices_descriptor, get_max_number_q_indices, &
       get_number_active_q_indices, set_q_index, standard_q_names


contains

  subroutine set_q_index(index, name)
    integer, intent(in) :: index
    character(len=*), intent(in) :: name

    q_register(index)%name=adjustr(trim(name))
    q_register(index)%l_used=.true.
  end subroutine set_q_index  

  integer function get_max_number_q_indices()
    get_max_number_q_indices=n_maxqs
  end function get_max_number_q_indices

  integer function get_number_active_q_indices()

    integer :: i

    get_number_active_q_indices=0
    do i=1, n_maxqs
      if (q_register(i)%l_used) get_number_active_q_indices=get_number_active_q_indices+1
    end do    
  end function get_number_active_q_indices  

  function get_indices_descriptor(i)
    integer :: i
    type(q_metadata_type) :: get_indices_descriptor
    
    get_indices_descriptor=q_register(i)
  end function get_indices_descriptor  

  integer function get_q_index(name, assigning_component)
    character(*), intent(in) :: name
    character(*), optional :: assigning_component

    integer :: iname, i_unused

    i_unused=0
    
    do iname=n_maxqs, 1, -1
      if (trim(name) == trim(q_register(iname)%name)) then
        ! Here we find the variable has already been added
        get_q_index=iname
        return
      end if
      ! Counting backwards we will eventually find the first open slot
      if (.not. q_register(iname)%l_used) then
        i_unused=iname
      end if
    end do

    if (i_unused == 0) then
      call log_master_log(log_error, 'Somehow we need to extend q_register')
    end if

    ! Not already defined, so populate the empty slot
    get_q_index=i_unused
    q_register(get_q_index)%name = adjustr(trim(name))
    q_register(get_q_index)%l_used = .true.

    if (present(assigning_component)) then
      call log_master_log(log_info, 'q variable #'//trim(conv_to_string(get_q_index))//' is assigned to '//trim(name)//&
           '. Assigned from component: '//trim(assigning_component))
    else
      call log_master_log(log_info, 'q variable #'//trim(conv_to_string(get_q_index))//' is assigned to '//trim(name))
    end if

  end function get_q_index
end module q_indices_mod